123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105106107108109110111112113114115116117118119120121122123124125126127128129130131132133134135136137138139140141142143144145146147148149150151152153154155156157158159160161162163164165166167168169170171172173174175176177178179180181182183184185186187188189190191192193 |
- *DECK DQK21
- SUBROUTINE DQK21 (F, A, B, RESULT, ABSERR, RESABS, RESASC)
- C***BEGIN PROLOGUE DQK21
- C***PURPOSE To compute I = Integral of F over (A,B), with error
- C estimate
- C J = Integral of ABS(F) over (A,B)
- C***LIBRARY SLATEC (QUADPACK)
- C***CATEGORY H2A1A2
- C***TYPE DOUBLE PRECISION (QK21-S, DQK21-D)
- C***KEYWORDS 21-POINT GAUSS-KRONROD RULES, QUADPACK, QUADRATURE
- C***AUTHOR Piessens, Robert
- C Applied Mathematics and Programming Division
- C K. U. Leuven
- C de Doncker, Elise
- C Applied Mathematics and Programming Division
- C K. U. Leuven
- C***DESCRIPTION
- C
- C Integration rules
- C Standard fortran subroutine
- C Double precision version
- C
- C PARAMETERS
- C ON ENTRY
- C F - Double precision
- C Function subprogram defining the integrand
- C FUNCTION F(X). The actual name for F needs to be
- C Declared E X T E R N A L in the driver program.
- C
- C A - Double precision
- C Lower limit of integration
- C
- C B - Double precision
- C Upper limit of integration
- C
- C ON RETURN
- C RESULT - Double precision
- C Approximation to the integral I
- C RESULT is computed by applying the 21-POINT
- C KRONROD RULE (RESK) obtained by optimal addition
- C of abscissae to the 10-POINT GAUSS RULE (RESG).
- C
- C ABSERR - Double precision
- C Estimate of the modulus of the absolute error,
- C which should not exceed ABS(I-RESULT)
- C
- C RESABS - Double precision
- C Approximation to the integral J
- C
- C RESASC - Double precision
- C Approximation to the integral of ABS(F-I/(B-A))
- C over (A,B)
- C
- C***REFERENCES (NONE)
- C***ROUTINES CALLED D1MACH
- C***REVISION HISTORY (YYMMDD)
- C 800101 DATE WRITTEN
- C 890531 Changed all specific intrinsics to generic. (WRB)
- C 890531 REVISION DATE from Version 3.2
- C 891214 Prologue converted to Version 4.0 format. (BAB)
- C***END PROLOGUE DQK21
- C
- DOUBLE PRECISION A,ABSC,ABSERR,B,CENTR,DHLGTH,
- 1 D1MACH,EPMACH,F,FC,FSUM,FVAL1,FVAL2,FV1,FV2,HLGTH,RESABS,RESASC,
- 2 RESG,RESK,RESKH,RESULT,UFLOW,WG,WGK,XGK
- INTEGER J,JTW,JTWM1
- EXTERNAL F
- C
- DIMENSION FV1(10),FV2(10),WG(5),WGK(11),XGK(11)
- C
- C THE ABSCISSAE AND WEIGHTS ARE GIVEN FOR THE INTERVAL (-1,1).
- C BECAUSE OF SYMMETRY ONLY THE POSITIVE ABSCISSAE AND THEIR
- C CORRESPONDING WEIGHTS ARE GIVEN.
- C
- C XGK - ABSCISSAE OF THE 21-POINT KRONROD RULE
- C XGK(2), XGK(4), ... ABSCISSAE OF THE 10-POINT
- C GAUSS RULE
- C XGK(1), XGK(3), ... ABSCISSAE WHICH ARE OPTIMALLY
- C ADDED TO THE 10-POINT GAUSS RULE
- C
- C WGK - WEIGHTS OF THE 21-POINT KRONROD RULE
- C
- C WG - WEIGHTS OF THE 10-POINT GAUSS RULE
- C
- C
- C GAUSS QUADRATURE WEIGHTS AND KRONROD QUADRATURE ABSCISSAE AND WEIGHTS
- C AS EVALUATED WITH 80 DECIMAL DIGIT ARITHMETIC BY L. W. FULLERTON,
- C BELL LABS, NOV. 1981.
- C
- SAVE WG, XGK, WGK
- DATA WG ( 1) / 0.0666713443 0868813759 3568809893 332 D0 /
- DATA WG ( 2) / 0.1494513491 5058059314 5776339657 697 D0 /
- DATA WG ( 3) / 0.2190863625 1598204399 5534934228 163 D0 /
- DATA WG ( 4) / 0.2692667193 0999635509 1226921569 469 D0 /
- DATA WG ( 5) / 0.2955242247 1475287017 3892994651 338 D0 /
- C
- DATA XGK ( 1) / 0.9956571630 2580808073 5527280689 003 D0 /
- DATA XGK ( 2) / 0.9739065285 1717172007 7964012084 452 D0 /
- DATA XGK ( 3) / 0.9301574913 5570822600 1207180059 508 D0 /
- DATA XGK ( 4) / 0.8650633666 8898451073 2096688423 493 D0 /
- DATA XGK ( 5) / 0.7808177265 8641689706 3717578345 042 D0 /
- DATA XGK ( 6) / 0.6794095682 9902440623 4327365114 874 D0 /
- DATA XGK ( 7) / 0.5627571346 6860468333 9000099272 694 D0 /
- DATA XGK ( 8) / 0.4333953941 2924719079 9265943165 784 D0 /
- DATA XGK ( 9) / 0.2943928627 0146019813 1126603103 866 D0 /
- DATA XGK ( 10) / 0.1488743389 8163121088 4826001129 720 D0 /
- DATA XGK ( 11) / 0.0000000000 0000000000 0000000000 000 D0 /
- C
- DATA WGK ( 1) / 0.0116946388 6737187427 8064396062 192 D0 /
- DATA WGK ( 2) / 0.0325581623 0796472747 8818972459 390 D0 /
- DATA WGK ( 3) / 0.0547558965 7435199603 1381300244 580 D0 /
- DATA WGK ( 4) / 0.0750396748 1091995276 7043140916 190 D0 /
- DATA WGK ( 5) / 0.0931254545 8369760553 5065465083 366 D0 /
- DATA WGK ( 6) / 0.1093871588 0229764189 9210590325 805 D0 /
- DATA WGK ( 7) / 0.1234919762 6206585107 7958109831 074 D0 /
- DATA WGK ( 8) / 0.1347092173 1147332592 8054001771 707 D0 /
- DATA WGK ( 9) / 0.1427759385 7706008079 7094273138 717 D0 /
- DATA WGK ( 10) / 0.1477391049 0133849137 4841515972 068 D0 /
- DATA WGK ( 11) / 0.1494455540 0291690566 4936468389 821 D0 /
- C
- C
- C LIST OF MAJOR VARIABLES
- C -----------------------
- C
- C CENTR - MID POINT OF THE INTERVAL
- C HLGTH - HALF-LENGTH OF THE INTERVAL
- C ABSC - ABSCISSA
- C FVAL* - FUNCTION VALUE
- C RESG - RESULT OF THE 10-POINT GAUSS FORMULA
- C RESK - RESULT OF THE 21-POINT KRONROD FORMULA
- C RESKH - APPROXIMATION TO THE MEAN VALUE OF F OVER (A,B),
- C I.E. TO I/(B-A)
- C
- C
- C MACHINE DEPENDENT CONSTANTS
- C ---------------------------
- C
- C EPMACH IS THE LARGEST RELATIVE SPACING.
- C UFLOW IS THE SMALLEST POSITIVE MAGNITUDE.
- C
- C***FIRST EXECUTABLE STATEMENT DQK21
- EPMACH = D1MACH(4)
- UFLOW = D1MACH(1)
- C
- CENTR = 0.5D+00*(A+B)
- HLGTH = 0.5D+00*(B-A)
- DHLGTH = ABS(HLGTH)
- C
- C COMPUTE THE 21-POINT KRONROD APPROXIMATION TO
- C THE INTEGRAL, AND ESTIMATE THE ABSOLUTE ERROR.
- C
- RESG = 0.0D+00
- FC = F(CENTR)
- RESK = WGK(11)*FC
- RESABS = ABS(RESK)
- DO 10 J=1,5
- JTW = 2*J
- ABSC = HLGTH*XGK(JTW)
- FVAL1 = F(CENTR-ABSC)
- FVAL2 = F(CENTR+ABSC)
- FV1(JTW) = FVAL1
- FV2(JTW) = FVAL2
- FSUM = FVAL1+FVAL2
- RESG = RESG+WG(J)*FSUM
- RESK = RESK+WGK(JTW)*FSUM
- RESABS = RESABS+WGK(JTW)*(ABS(FVAL1)+ABS(FVAL2))
- 10 CONTINUE
- DO 15 J = 1,5
- JTWM1 = 2*J-1
- ABSC = HLGTH*XGK(JTWM1)
- FVAL1 = F(CENTR-ABSC)
- FVAL2 = F(CENTR+ABSC)
- FV1(JTWM1) = FVAL1
- FV2(JTWM1) = FVAL2
- FSUM = FVAL1+FVAL2
- RESK = RESK+WGK(JTWM1)*FSUM
- RESABS = RESABS+WGK(JTWM1)*(ABS(FVAL1)+ABS(FVAL2))
- 15 CONTINUE
- RESKH = RESK*0.5D+00
- RESASC = WGK(11)*ABS(FC-RESKH)
- DO 20 J=1,10
- RESASC = RESASC+WGK(J)*(ABS(FV1(J)-RESKH)+ABS(FV2(J)-RESKH))
- 20 CONTINUE
- RESULT = RESK*HLGTH
- RESABS = RESABS*DHLGTH
- RESASC = RESASC*DHLGTH
- ABSERR = ABS((RESK-RESG)*HLGTH)
- IF(RESASC.NE.0.0D+00.AND.ABSERR.NE.0.0D+00)
- 1 ABSERR = RESASC*MIN(0.1D+01,(0.2D+03*ABSERR/RESASC)**1.5D+00)
- IF(RESABS.GT.UFLOW/(0.5D+02*EPMACH)) ABSERR = MAX
- 1 ((EPMACH*0.5D+02)*RESABS,ABSERR)
- RETURN
- END
|